@echo off

:: ====================================
:: 바로가기 Start
:: ====================================

:: [1] 바로가기 생성 함수 ========================================================================
set SUCCESS=1
set SYSTEM=eTopia
set NAME=eTopia접속
set URL=https://ga.idblife.com
set ICONURL=https://etopia.idblife.com/favicon.ico
set ICONPATH=%temp%\favicon_%SYSTEM%.ico

set CHROMEPATH=

:: [2] Chrome 경로 탐색 ==========================================================================
for /f "tokens=2*" %%A in (
 'reg query "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\App Paths\chrome.exe" /ve 2^>nul'
) do set CHROMEPATH=%%B

if not defined CHROMEPATH (
	echo 설치된 Chrome을 찾을 수 없습니다. Chrome을 설치 후 바로가기생성을 해주세요.
	set SUCCESS=0
	goto END
)

:: [3] AS-IS 바로가기 삭제 =======================================================================
del "%PUBLIC%\Desktop\Etopia 접속.lnk" 2>nul
del "%userprofile%\Desktop\Etopia 접속.lnk" 2>nul

:: [4] 기생성 바로가기 삭제 ======================================================================
del "%userprofile%\Desktop\%NAME%.lnk" 2>nul

:: [5] Icon 다운로드 =============================================================================
powershell -command "Invoke-WebRequest '%ICONURL%' -OutFile '%ICONPATH%'"

:: [6] 바로가기 생성 스크립트 ====================================================================
echo Set oWS = WScript.CreateObject("WScript.Shell") > %temp%\createShortcut.vbs
echo sLinkFile = "%userprofile%\Desktop\%NAME%.lnk" >> %temp%\createShortcut.vbs
echo set olink = oWS.CreateShortcut(sLinkFile) >> %temp%\createShortcut.vbs
echo olink.TargetPath = "%CHROMEPATH%" >> %temp%\createShortcut.vbs
echo olink.Arguments = "%URL%" >> %temp%\createShortcut.vbs
echo olink.IconLocation = "%ICONPATH%" >> %temp%\createShortcut.vbs
echo olink.Save >> %temp%\createShortcut.vbs

:: [7] 바로가기 생성 스크립트 실행 ===============================================================
cscript //nologo %temp%\createShortcut.vbs

:: [8] 바로가기 생성 스크립트 파일 삭제 ==========================================================
del %temp%\createShortcut.vbs

:END
if %SUCCESS%==1 (
    echo 바로가기 설치가 완료되었습니다.
) else (
    pause
)